SQL embarqué Profitez de la puissance de SQL dans votre RPG

SQL embarqué Profitez de la puissance de SQL dans votre RPG 16 et 17 mai 2011 IBM Forum de Bois-Colombes Session 3 Lundi 16 mai 14h00/15h30 Nathanaël BONNET GAIA Mini Systèmes nbonnet@gaia.fr

AGENDA SQL, un langage ensembliste SQL statique et SQL dynamique Simplifiez vos développements : une instruction SQL peut remplacer des centaines de lignes de programme! Principes de l'optimiseur SQL, contraintes et bonnes pratiques 2

GAIA : EXPERTISE CONSEIL ET FORMATION DEPUIS 1999 NOS DOMAINES DE COMPETENCES IBM i Lotus Domino Java / Websphere Technologies Web EXPERTISES Système Migration, optimisation Développement Méthodologie, conseil, assistance technique Accompagnement Conduite du changement, support aux équipes 3

KNOW 400 : DISPOSITIF DE CAPITALISATION BASE DE CONNAISSANCES WEB WWW.KNOW400.FR 4

KNOW 400 : DISPOSITIF DE CAPITALISATION BASE DE CONNAISSANCES IBM i RPG IV, ILE, Web Services, SQL Exploitation,Système CONTENUS THEMATIQUES BASE D EXERCICES ET D EXEMPLES PARCOURS FORMATION SERVICES ASSOCIES Tutorat, formation online, conseil online WWW.KNOW400. FR 5

SQL embarque 6

Structured Query Language Le langage standard de manipulation de données Présent dans tous les SGBD Mais non portable d un SGBD a un autre Chaque éditeur «enrichissant» le standard de sa propre syntaxe ou fonctionnalité Langage ensembliste Manipule un ensemble de données De 0 à n enregistrements Contrairement à RPG Enregistrement par enregistrement La première version commerciale 1979 7

Structured Query Language C est le langage incontournable sur toutes les plateformes Sur IBM i De nombreuses évolutions au fil des ans IBM a stabilisé le DDS, seul SQL évolue Nouveaux types de donnée Nouvelles fonctionnalités 8

Structured Query Language 9

Structured Query Language SQL est composé de plusieurs langages, chacun dédié à une utilisation DML (Data Manipulation language) Permet de sélectionner, insérer, supprimer ou modifier des données dans une table (des tables) d une base de données relationnelle DDL (Data Definition Language) Permet de définir les structures de données, c est-à-dire les tables, les index et les contraintes DCL (Data Control Language) Gestion des autorisations, au niveau des objets comme au niveau colonne PL/SQL (Procedural Language) Langage de programmation SQL pour les SGBD : procédures stockées, fonctions utilisateurs, triggers SQL embarqué DML, DDL, DCL et des éléments de PL/SQL disponibles pour les langages de programmation 10

SQL sur IBM i Particularité DB2 for i Intégré à l OS Gestion d équivalent avec DB2 natif De multiples interfaces SQL Interactif (STRSQL) Exécution de scripts SQL (RUNSQLSTM) SQL embarqué Query Manager (QM) SQL interactif par iseries Navigator 11

SQL sur IBM i Vocabulaire IBM i Bibliothèque Fichier physique Enregistrement Champ Logique à clé Logique sans clé DB2 for i Schéma ou collection Table Ligne Colonne Index Vue 12

SQL embarqué Pourquoi? Gestion plus souple des sélection Evite de multiplier les vues Remplacer les cartes F C est le langage informatique le plus universel Permet de réduire le lien programme fichier 13

SQL embarqué Comment? Membre SQLRPGLE Supporté aussi pour C, C++, COBOL, RPG/400, REXX Format libre (depuis 5.4) exec sql instruction SQL ; Possible en 5.3 avec PTF Format fixe c/exec sql c+ instruction SQL c/end-exec Compilation CRTSQLRPGI OBJTYPE(*PGM) pour un programme OBJTYPE(*MODULE) pour un module 14

SQL embarqué Compilation En deux étapes Membre source exec sql CALL SQLROUTE Pré-compilation SQL -Syntaxe SQL -Conversion SQL vers appel API SQL -Insertion des déclarations nécessaires Source modifié temporaire Compilation RPG - Syntaxe RPG - Cartes F - *PGM SQL Inf. 15

SQL embarqué Compilation 16

SQL embarqué Principaux paramètres de compilation CLOSQLCSR précise la portée de vos curseurs (groupe d activation ou module) DATFMT,DATSEP,TIMFMT,TIMSEP formats de date et d heure COMMIT pour le contrôle de validation DYNUSRPRF User pour les requêtes dynamiques Etc 17

SQL embarqué Vous pouvez indiquez ces paramètres soit Quand vous compilez CRTSQLRPGI.COMMIT(*NONE) DATFMT(*ISO) Dans le programme pour éviter de les oublier C/Exec SQL C+ Set Option Commit=*NONE, DatFmt=*ISO, DynUsrPrf=*OWNER, DlyPrp=*YES C/End-Exec Sauf DBGVIEW Préférable afin de mémoriser ces options Ce doit être la première instruction SQL 18

Variable hôte C est une variable RPG Utilisable dans une instruction SQL (statique) Définie en carte D ou en carte F pour un DSPF Syntaxe :variable Utilisable Clause WHERE Réception de colonne pour SELECT ou FETCH Valeur dans une clause SELECT Autres instructions UPDATE SET INSERT VALUES CALL 19

Syntaxe IBM i SELECT INTO Permet de récupérer dans des variables hôtes les valeurs retournées par l instruction SELECT Les variables hôtes sont utilisables Clause INTO Clause WHERE Dans la liste des valeurs de la clause SELECT D getemployee S 6a D name S 15a D deptno S 3a /free getemployee = '00001'; Exec SQL Select lastname, workdept Into :name, :deptno From Employee Where empno = :getemployee ; Dsply Name; 20

Syntaxe IBM i SELECT INTO Le type des variables hôtes doit correspondre avec le type de la zone dans le fichier (DDS ou SQL) Pour trouver l équivalence de types IBM i 7.1 Information Center > Base de données > Programmation > Embedded SQL programming > Coding SQL statements in ILE RPG applications > Determining equivalent SQL and ILE RPG data types Mettre le fichier concerné en carte F ou en DS extname et consultez le spoule de compilation 21

Syntaxe IBM i UPDATE Les variables hôtes sont utilisables Clause SET Clause WHERE D wbonus S 9s 2 D deptno S 3a /free deptno = E21 ; wbonus = 100 ; exec sql UPDATE Employee SET Salary = Salary + (Salary *.10), Bonus = :wbonus WHERE WorkDept = :deptno ; 22

Syntaxe IBM i DELETE Les variables hôtes sont utilisables Clause WHERE D deptno S 3a /free deptno = E21 ; exec sql DELETE from Employee WHERE WorkDept = :deptno ; 23

Syntaxe IBM i INSERT Les variables hôtes sont utilisables Clause VALUES /free // Syntaxe 1 : colonnes énumérées exec sql INSERT Into Employee ( Empno, FName, LastName, WorkDept ) Values( :employeeno, :First, :Last, 'E21' ); // Syntaxe 2 : toutes les colonnes exec sql INSERT Into Employee Values( :employeeno, :First, '', :Last, 'E21',... ) ; 24

Syntaxe IBM i Utilisation de DS Permet de remplacer une liste de valeurs Simplifie le SELECT INTO Les sous-zones de DS doivent correspondre aux colonnes sélectionnées Nombre, type, ordre DS Interne D employeeinfo DS D employeeno 6a D lastname 15a D salary 9p 2 D getemployee S 6a /free EXEC SQL SELECT EmpNo, LastName, Salary INTO :employeeinfo FROM Employee WHERE Empno = :getemployee ; 25

Syntaxe IBM i DS Externe EXTNAME uniquement LIKEREC ne fonctionne pas La pré-compilation SQL s effectue avant la compilation RPG qui analyse les cartes F Utilisable uniquement avec SELECT * D employeedata E DS extname(employee) D getemployee S 6a /free EXEC SQL SELECT * INTO :employeedata FROM Employee WHERE Empno = :getemployee ; 26

Syntaxe IBM i Options pour les DS QUALIFIED Supportée DIM Supportée uniquement dans les clauses SELECT INTO et INSERT VALUES pour l ensemble des occurrences On en reparlera DS imbriquées (qualified) Non supportées La syntaxe. du RPG n est pas supportée par le pré-compilateur SQL 27

Syntaxe IBM i Options pour les DS Exemples en ERREUR de pré-compilation D employeedata E DS extname(employee) D qualified D dim( 10 ) /free employeedata( 1 ).EmpNo = '000020' ; EXEC SQL SELECT * INTO :employeedata FROM Employee WHERE Empno = :employeedata( 1 ).EmpNo ; dsply ( employeedata( 1 ).EMPNO + ' ' + employeedata( 1 ).FIRSTNME ) ; SQL0312 : Variable non définie ou inutilisable D employeedata E DS extname(employee) D qualified D template D employe DS qualified D FromBD likeds( employeedata ) inz D OtherInfos 100a inz /free employe.frombd.empno = '000020' ; EXEC SQL SELECT * INTO :employe.frombd.empno FROM Employee WHERE Empno = :employe.frombd.empno ; dsply ( employe.frombd.empno + ' ' + employe.frombd.firstnme ) ; SQL0104 : Elément syntaxique. n est pas correct. 28

Curseur Ils sont utiles Pour lire plusieurs enregistrements d une même sélection Cinématique Déclarer le curseur Ouvrir le curseur Effectue la sélection Lire les enregistrements en boucle Faire quelque chose avec votre enregistrement Fermer le curseur 29

Curseur DECLARE CURSOR Déclare le curseur en association avec une requête Des variables hôtes peuvent être utilisées dans la clause WHERE de la requête Dans tout le programme (module) Un seul curseur du même nom EXEC SQL DECLARE EmpCursor CURSOR FOR SELECT EmpNo, LastName, Salary FROM Employee WHERE WorkDept = :Dept ORDER BY EmpNo ; 30

Curseur DECLARE CURSOR Pensez bien à mettre ORDER BY si l ordre des enregistrements est important pour votre traitement Utilisez FOR READ ONLY Performance FOR UPDATE OF liste de colonnes Empêche la modification d une colonne non listée 31

Curseur OPEN CURSOR Ouverture du curseur C est à ce moment que la requête est exécutée Constitution du result set EXEC SQL OPEN EmpCursor ; 32

Curseur FETCH Parcours du result set Place les valeurs d une ligne de result set dans les variables hôtes C est l instruction qui permet de passer d un langage SQL ensembliste (traite n enregistrements simultanément) au langage RPG séquentiel (traite un enregistrement puis un autre) EXEC SQL FETCH NEXT FROM EmpCursor INTO :employeeno,:lastname,:salary ; 33

Curseur Curseur flottant Si vous devez vous déplacer dans le curseur DYNAMIC SCROLL FETCH NEXT, PRIOR, FIRST, LAST FETCH RELATIVE N Déplacement de N enregistrements (N peut être négatif ou =0) EXEC SQL DECLARE EmpCursor SCROLL CURSOR FOR SELECT EmpNo, LastName, Salary FROM Employee WHERE WorkDept = :Dept ORDER BY EmpNo ; EXEC SQL FETCH PRIOR FROM EmpCursor INTO :employeeno,:lastname,:salary; 34

Curseur CLOSE Fermeture du curseur Il doit être ouvert A défaut, le curseur est fermé A la fin du module ou à la fin du groupe d activation A la fin du job EXEC SQL CLOSE EmpCursor ; 35

CURSOR FOR UPDATE OF Pour un curseur déclaré avec FOR UPDATE OF Il est possible de modifier ou supprimer la ligne courante (le dernier FETCH) EXEC SQL UPDATE Employee SET salary = salary + :raise WHERE CURRENT OF EmpCursor; EXEC SQL DELETE Employee WHERE CURRENT OF EmpCursor; 36

Curseur exemple complet D WrkEmployee E DS extname(employee) D qualified /free EXEC SQL DECLARE C1 CURSOR FOR SELECT * FROM Employee WHERE WorkDept = 'D11' FOR READ ONLY ; EXEC SQL OPEN C1 ; EXEC SQL FETCH C1 INTO :WrkEmployee ; dow SqlCode >= 0 and SqlCode < 100 ; dsply ( 'ID / Nom : ' + WrkEmployee.EMPNO + ' / ' + WrkEmployee.LASTNAME ) ; EXEC SQL FETCH C1 INTO :WrkEmployee ; EndDo ; EXEC SQL CLOSE C1 ; return ; /end-free 37

Syntaxe IBM i Sélections multiples et insertion multiples Meilleur performance et parfois plus simple (vous connaissez à l avance le nombre maximal de valeurs à traiter) Nécessite une DS à dimension (DIM) Pour FETCH, le nombre de lignes lues est disponible dans SQLErrd(3) On en reparle 38

Syntaxe IBM i D employeelist E DS extname(employee) D qualified D dim( 20 ) /free EXEC SQL DECLARE C1 CURSOR FOR SELECT * FROM Employee WHERE WorkDept = 'D11' ; EXEC SQL OPEN C1 ; EXEC SQL FETCH C1 FOR 20 ROWS INTO :employeelist ; dsply ( 'Nb de lignes lues : ' + %char( SQLErrd( 3 ) ) ) ; EXEC SQL CLOSE C1 ; D employeelist E DS extname(employee) D qualified D dim( 20 ) d NbrEmployee s 10i 0 inz( 12 ) /free EXEC SQL INSERT INTO Employee :NbrEmployee ROWS VALUES (:employeelist ) ; 39

Gestion des erreurs SQLCA (SQL Communication Area) Le pré-compilateur RPG ajoute automatiquement une DS SQLCA Contient des zones qui nous renseigne sur le statu de l instruction SQL précédente Aussi bien en cas d anomalie que de fin correcte Des zones de diagnostic Les zones les plus importantes SQLCODE Code retour, propre à DB2 for i SQLSTATE Code retour, norme SQL 1999 SQLCOD et SQLSTT pour compatibilité avec programmes migrés depuis RPG/400 40

Gestion des erreurs D SQLCA DS D SQLCAID 8A INZ(X'0000000000000000') D SQLAID 8A OVERLAY(SQLCAID) D SQLCABC 10I 0 D SQLABC 9B 0 OVERLAY(SQLCABC) D SQLCODE 10I 0 D SQLCOD 9B 0 OVERLAY(SQLCODE) D SQLERRML 5I 0 D SQLERL 4B 0 OVERLAY(SQLERRML) D SQLERRMC 70A D SQLERM 70A OVERLAY(SQLERRMC) D SQLERRP 8A D SQLERP 8A OVERLAY(SQLERRP) D SQLERR 24A D SQLER1 9B 0 OVERLAY(SQLERR:*NEXT) D SQLER2 9B 0 OVERLAY(SQLERR:*NEXT) D SQLER3 9B 0 OVERLAY(SQLERR:*NEXT) D SQLER4 9B 0 OVERLAY(SQLERR:*NEXT) D SQLER5 9B 0 OVERLAY(SQLERR:*NEXT) D SQLER6 9B 0 OVERLAY(SQLERR:*NEXT) D SQLERRD 10I 0 DIM(6) OVERLAY(SQLERR) D SQLWRN 11A D SQLWARN 1A DIM(11) OVERLAY(SQLWRN) D SQLSTATE 5A D SQLSTT 5A OVERLAY(SQLSTATE) 41

Gestion des erreurs SQLCODE = 0 exécution OK > 0 avertissement < 0 erreur = 100 pas de donnée (FETCH) *MSGF QSQLMSG SQLnnnn Si nnnnn < 10000 SQnnnnn Si nnnnn >= 10000 42

Gestion des erreurs SQLSTATE C est le standard recommandé dans le monde SQL SQLCODE SQLSTATE SQL Succès 0 00... Avertissement > 0 01 WHENEVER SQLWARNING Pas de donnée = 100 02 WHENEVER SQL NOT FOUND Erreur < 0 >= 03 WHENEVER SQLERROR 43

Gestion des valeurs nulles SQL peut admettre des valeurs nulles RPG ne peut pas Un «indicateur» est couplé à la variable hôte afin de détecter ou signaler la nullité Variable binaire sur 1 octet (3I0) D anniv s d datfmt( *iso ) D annivind s 3i 0 inz D getemployee S 6a inz( '000020' ) /free EXEC SQL SELECT birthdate INTO :anniv :annivind FROM Employee WHERE Empno = :getemployee ; if annivind <> 0 ; dsply 'Valeur nulle' ; else ; dsply ( %char( anniv ) ) ; endif ; 44

SQL statique et dynamique 45

SQL Dynamique Avantages Requête construite en dynamique en fonction du contexte d exécution Multicritères Fichier dans une bibliothèque absente de *LIBL Beaucoup plus souple! Inconvénients Performance Le plan d exécution de la requête n est pas connu à la compilation Plus de code Il faut écrire le code RPG qui construit la requête SQL Exécuter la requête 46

SQL Dynamique 1 ère syntaxe marequete = CREATE TABLE EXEC SQL PREPARE monstmt FROM :marequete ; EXEC SQL EXECUTE monstmt ; 2 nde syntaxe marequete = UPDATE EXEC SQL EXECUTE IMMEDIATE :marequete ; EXECUTE IMMEDIATE remplace PREPARE + EXECUTE Syntaxe pour les curseurs marequete = SELECT EXEC SQL PREPARE monstmt FROM :marequete ; EXEC SQL DECLARE C1 CURSOR FOR monstmt ; 47

SQL Dynamique Marqueur Impossibilité d utiliser des variables hôtes en SQL dynamique Utilisation du marqueur de paramètre? Insère dynamiquement lors de l exécution de l instruction les valeurs contenues dans les variables spécifiées Une instruction qui a été préparée (PREPARE) peut ainsi être exécutée plusieurs fois avec des valeurs différentes pour les «paramètres»? if deletedepartment; condition = 'WorkDept =?' ; else ; condition = 'EmpNo =?'; endif; mysqlstatement = 'Delete From Employee Where ' + Condition; EXEC SQL PREPARE DynamicSQL FROM :mysqlstatement; if (SQLCode = 0 And SQLWarn0 = *Blank); EXEC SQL EXECUTE DynamicSQL Using :InputValue; endif; 48

Simplifiez vos développements 49

Exemples SQL peut vous simplifier la vie dans de nombreuses situations Lorsque l accès par RPG nécessite un index (logique) inexistant Sélections multicritères Plus globalement, toutes les opérations ensembliste que l on peut réaliser en dehors du mode «ligne à ligne» Supprimer tous les enregistrements présents dans le fichier A et dont la clé n existe pas dans le fichier B Tous les enregistrements en communs 50

Exemple Curseur en MAJ EXEC SQL DECLARE c1 NO SCROLL CURSOR WITHOUT RETURN FOR SELECT * FROM xrefscd WHERE exec_mode <> '*STOP' ORDER BY VERSION FOR UPDATE OPTIMIZE FOR 1 ROWS ; EXEC SQL OPEN c1 ; EXEC SQL -- Première fiche FETCH c1 FOR 1 ROWS INTO :enreg ; dow sqlstate < '02000' ; // Traiter chaque ligne // Traitement ici EXEC SQL UPDATE xrefscd SET last_exec_sbm = CURRENT_TIMESTAMP, last_exec_mode = :wmode, last_exec_date = DATE(:wlastxref) WHERE CURRENT OF c1 ; if sqlstate <> '00000' ; // Faire quelque chose endif ; endif ; // Fiche suivante EXEC SQL FETCH c1 FOR 1 ROWS INTO :enreg ; enddo ; 51

Exemple Sélection multiple p alimxref b d alimxref pi // variables locales d LDst_TypeXRef ds qualified d dim( 6 ) d inz d Car_Type 10a inz // nombres de type de Xref différents d LEns_Cptw s 3u 0 inz /free... exec sql declare c_typxref cursor for select distinct xrobjt from arcad_prd/ardxref0 where xrobjt in ( '*VTOM', '*ODI', '*TOP', '*PARMAP', '*TFRFIC', '*NET') and xrpnam = :GCar_NomCmp and xrapp = :GCar_AppId order by xrobjt ; exec sql open c_typxref ; exec sql fetch c_typxref for 6 rows into :LDst_TypeXRef ; exec sql close c_typxref ; 52

Exemple SQL dynamique p DropProcedure... p b d pi n d PCar_ProcSpecificName... d 128a value d PCar_ProcSpecificLib... d 128a value // variables locales d LCar_Stmt... d s 1024a inz /free LCar_Stmt = 'DROP SPECIFIC PROCEDURE ' + %trim( PCar_ProcSpecificLib ) + '/' + %trim( PCar_ProcSpecificName ) ; Exec Sql PREPARE S1 FROM :LCar_Stmt ; Exec Sql EXECUTE S1 ; return ( SQLCODE >= 0 and SQLCODE < 100 ) ; /end-free // fin p DropProcedure... p e 53

Exemple Complexe 1/4 p dolist b export d pi d PCar_DateRef 7a value // variables d LCar_DateRef s 8a /free // Date de référence : transmise ou aujourd'hui? if PCar_DateRef = *all'0' ; LCar_DateRef = %char( %date() : *iso0 ) ; else ; LCar_DateRef = %char( %date( %subst( PCar_DateRef : 2 : 6 ) : *YMD0 ) : *iso0 ) ; endif ; // Suppression du fichier si existant exec sql drop table qtemp/extcmpd ; 54

Exemple Complexe 2/4 // création de la table // nécessaire, sinon on a des CCSID à 65535 (colonne CHAR FOR BIT DATA) exec sql CREATE TABLE qtemp/extcmpd ( GF CHAR(4) CCSID 297 DEFAULT NULL, "Quartier" FOR COLUMN QUART00001 CHAR(50) CCSID 297 DEFAULT NULL, "Ilot" FOR COLUMN ILOT_00001 CHAR(50) CCSID 297 DEFAULT NULL, "Composant" FOR COLUMN COMPO00001 CHAR(10) CCSID 297 DEFAULT NULL, "Type source" FOR COLUMN TYPE_00001 CHAR(10) CCSID 297 DEFAULT NULL, "Type objet" FOR COLUMN TYPE_00002 CHAR(8) CCSID 297 DEFAULT NULL, "Texte objet" FOR COLUMN TEXTE00001 CHAR(50) CCSID 297 DEFAULT NULL, "Programmeur" FOR COLUMN PROGR00001 CHAR(10) CCSID 297 DEFAULT NULL, "Date création" FOR COLUMN DATE_00001 DATE DEFAULT NULL, "Version" FOR COLUMN VERSI00001 CHAR(8) CCSID 297 DEFAULT NULL, "Chef Projet" FOR COLUMN CHEF_00001 CHAR(10) CCSID 297 DEFAULT NULL, "Date ouverture" FOR COLUMN DATE_00002 DATE DEFAULT NULL ) ; 55

Exemple Complexe 3/4 // Alimentation exec sql insert into qtemp/extcmpd -- liste des versions ouvertes / CP with lstver as ( select ver.vrapp as "Appli", ver.vrvers as "Version", ver.vrtxt as "Texte", ver.vrdcld as "Date ouverture", team.stpgmr as "Chef Projet" from arcad_prd/armverf1 ver join arcad_prd/armstff1 team on ver.vrapp = team.stapp and ver.vrtst = team.sttst and ver.vrvers = team.stver where ver.vrmexd = 0 and -- Version ouverte team.stfonc = 'P' -- Chef de projet ), lstsrc as ( -- liste des composants avec sources select src.mssrcm as "Composant", src.mstype as "Type source", // le reste de l instruction est tronquée ici... 56

Exemple Complexe 4/4 -- Sélection finale : select lstfinale."gf", lstfinale."quartier", lstfinale."ilot", lstfinale."composant", lstfinale."type source", lstfinale."type objet", lstfinale."texte objet", lstfinale."programmeur", cast( timestamp_format( char( lstfinale."date création" ), 'YYYYMMDD' ) as DATE ) as "Date création", lstfinale."version", lstfinale."chef Projet", cast( timestamp_format( char( lstfinale."date ouverture" ), 'YYYYMMDD' ) as DATE ) as "Date ouverture" from lstfinale where lstfinale."date création" >= :LCar_DateRef ; // fini return ; /end-free p e 57

Optimiseur bonnes pratiques 58

SET OPTION NAMING *SYS Bibliothèque/fichier Recherche des fichiers non qualifiés en *LIBL *SQL Bibliothèque.fichier Considère que tous les fichiers sont dans un unique schéma (bibliothèque) dont le nom par défaut est le profil utilisateur en cours Recommandation *SYS pour *LIBL : mode de fonctionnement de nos applications historiquement non SQL 59

SET OPTION DATFMT, TIMFMT SQL ne gère pas de format de date en stockage, contrairement à DDS *ISO Ce format représente le format de date à utiliser pour toute instruction SQL Représentation des dates (constantes ou variables alphanumériques et numériques) Chaque variable hôte (utilisée dans une instruction SQL) devra être dans ce format Recommandation *ISO 60

SET OPTION COMMIT Par défaut *CHG Fichiers journalisés Nécessite COMMIT explicite Fichiers non journalisés Plantage : SQL inutilisable sur ces fichiers Recommandation Si vous n utilisez pas déjà le contrôle transactionnel, utilisez la valeur *NONE 61

Autres recommandations SELECT * A proscrire Enoncer les colonnes à retourner INSERT INTO Faire des insert énoncés et non simplifiés INSERT INTO table (zone1, zone2) VALUES(9999, 'n') au lieu de INSERT INTO table VALUES(9999, 'n') La raison est la même pour les deux cas Changement de structure de la table 62

Autres recommandations Utiliser NAMING = *SYS Ne pas qualifier les fichiers Travailler avec la *LIBL Préférer le mode statique Meilleur performance Le plan d exécution est pré-calculé et stocké dans le programme Fermetures de curseur Veiller à gérer les fermetures Soit explicite par CLOSE Soit implicite par le groupe d activation 63

Autres recommandations Spécifiez le maximum d options sur instructions DECLARE CURSOR et SELECT FOR FETCH/READ ONLY ou FOR UPDATE OF colonnes FETCH FIRST n ROWS ONLY CURSOR DECLARE CURSOR doit être avant OPEN Dans l ordre des n de séquence du source! Sinon, le pré-compilateur estime que l on fait un OPEN sans déclaration préalable 64

Optimiseur Avant d exécuter votre requête, l optimiseur SQL va chercher le moyen le plus rapide de la faire, en fonction Du nombre d enregistrements de la table Des indexs existants Des statistiques d accès C est le plan d exécution 65

Optimiseur Il est possible de retrouver des informations du plan d exécution et de l optimiseur En natif STRDBG STRSQL La log de votre travail contient des messages de l optimiseur Pour chaque clé et index, s il est utilisé ou non, et pourquoi Suggestion d index à créer Etc 66

Optimiseur 67

Optimiseur Par System i Navigator Dans l exécution de script SQL 68

MERCI 69